Il tasto BLOC MAIUSC occupa lo spazio principale della tastiera e non ne sta facendo il peso. Questo semplice script AutoHotkey trasformerà Caps Lock in un tasto modificatore in modo da poterlo utilizzare per scorciatoie personalizzabili.
Sommario:
Le basi
Questo script ti consente di premere Caps Lock + G per visualizzare rapidamente il testo di Google da qualsiasi punto di Windows o premere Caps Lock + D per cercare la definizione del dizionario di una parola. Queste scorciatoie sono personalizzabili, ovviamente.
Soprattutto, questo script intelligente ti consente comunque di utilizzare normalmente Caps Lock. Puoi attivare e disattivare il blocco maiuscole premendolo rapidamente due volte. Se non lo fai, Caps Lock funzionerà come un tasto di modifica per le scorciatoie.
AutoHotkey 101
AutoHotkey è un’applicazione Windows gratuita che si trova in background ed esegue script. Puoi scrivere questi script da solo o scaricarli. Gli script generalmente attendono la pressione di un tasto ed eseguono un’azione. In questo modo, AutoHotkey è un modo rapido per rimappare i tasti in Windows o assegnare diverse azioni ai tasti.
Ad esempio, abbiamo mostrato come utilizzare AutoHotkey per disabilitare il tasto Windows, impedendogli di aprire il menu Start e di portarti fuori dai giochi per PC a schermo intero. Non c’è bisogno di staccare il keycap dalla tastiera.
Installa AutoHotkey e ottieni lo script
Scarica AutoHotkey e installalo per iniziare. Quindi, scarica lo script CapsLock Modifier.
Estrai il file di script AHK dal file di archivio ZIP e posizionalo in una cartella qualsiasi del tuo computer. Per eseguirlo con AutoHotkey, fare clic con il pulsante destro del mouse sullo script e selezionare “Esegui script”.
Lo script è ora in esecuzione in background. Per attivare e disattivare Caps Lock, tocca due volte rapidamente il tasto Caps Lock.
Se non tocchi due volte, Caps Lock funziona solo come un tasto di modifica. Con le funzioni integrate nello script, puoi utilizzare le seguenti scorciatoie ovunque in Windows:
Premi BLOC MAIUSC + D per trovare la definizione del dizionario di una parola selezionata.
Premi BLOC MAIUSC + G per cercare su Google il testo selezionato ovunque in Windows.
Premi BLOC MAIUSC + T per trovare la parola selezionata in un thesaurus.
Premi BLOC MAIUSC + W per cercare il testo selezionato su Wikipedia.
Vuoi più scorciatoie? Puoi crearne uno tuo con una piccola conoscenza degli script AutoHotkey.
Per controllare AutoHotkey, cerca l’icona AutoHotkey nell’area di notifica: ha uno sfondo verde con una H bianca. Per interrompere l’esecuzione dello script, fai clic con il pulsante destro del mouse sull’icona AutoHotkey e seleziona “Esci”.
Come funziona?
Se desideri vedere cosa fa lo script, fai clic con il pulsante destro del mouse e seleziona invece “Modifica script”. Questo aprirà lo script in Blocco note e potrai esaminarne il codice. La sceneggiatura è piuttosto breve e facile da capire. Si consiglia di non scaricare ed eseguire strani script senza prima guardarli e capirli.
Questo script ci è stato inviato da Dave Kellog. Ecco la parte magica dello script che fa funzionare Caps Lock come un tasto modificatore se viene premuto due volte:
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
Questo bit attende di vedere se Caps Lock viene premuto due volte e attiva o disattiva Caps Lock. In caso contrario, lo script acquisisce Caps Lock e lo utilizza per le scorciatoie dei modificatori.
Il resto dello script contiene le azioni di scelta rapida e un’utile funzione degli appunti che salva i contenuti degli appunti e li ripristina. Quella parte è abbastanza necessaria, poiché le funzioni di modifica utilizzano gli appunti per eseguire azioni sul testo selezionato.
Vuoi vedere lo script completo senza scaricarlo? Ecco qui:
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
;================================================================================================
; CapsLock processing. Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
;================================================================================================
; Hot keys with CapsLock modifier. See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.
CapsLock & d::
ClipboardGet()
Run, https://www.google.com/search?q=define+%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; GOOGLE the selected text.
CapsLock & g::
ClipboardGet()
Run, https://www.google.com/search?q=%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do THESAURUS of selected word
CapsLock & t::
ClipboardGet()
Run https://www.thesaurus.com/browse/%Clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do WIKIPEDIA of selected word
CapsLock & w::
ClipboardGet()
Run, https://en.wikipedia.org/wiki/%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
OldClipboard:= ClipboardAll ;Save existing clipboard.
Clipboard:= ""
Send, ^c ;Copy selected test to clipboard
ClipWait 0
If ErrorLevel
{
MsgBox, No Text Selected!
Return
}
}
ClipboardRestore()
{
Clipboard:= OldClipboard
}
Abbiamo già visto script AutoHotkey che trasformano Caps Lock in un tasto modificatore, ma mai uno che mantiene Caps Lock in giro come interruttore se lo premi due volte. È molto intelligente. Grazie ancora a Dave Kellog per avercelo inviato.